Skip to content
Open
Show file tree
Hide file tree
Changes from all commits
Commits
File filter

Filter by extension

Filter by extension

Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
Original file line number Diff line number Diff line change
@@ -0,0 +1,7 @@
#> asset:artifact/1634.call_glove_creepers/give/1.trigger
#
# 神器の取得処理の呼び出し時に実行されるfunction
#
# @within tag/function asset:artifact/give

execute if data storage asset:context {id:1634} run function asset:artifact/1634.call_glove_creepers/give/2.give
Original file line number Diff line number Diff line change
@@ -0,0 +1,71 @@
#> asset:artifact/1634.call_glove_creepers/give/2.give
#
# 神器の作成部 ここでID等を定義する
#
# @user
# @within function asset:artifact/1634.call_glove_creepers/give/1.trigger

# 神器の説明や消費MPなどをここで設定する。
# 最後にasset:artifact/common/giveを実行することで入手可能。

# 神器のID (int) スプレッドシートの値を入れる
data modify storage asset:artifact ID set value 1634
# 神器のベースアイテム
data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
# 神器の名前 (TextComponentString)
data modify storage asset:artifact Name set value '{"text":"コール:グローブ・クリーパーズ","color":"#6CEB35"}'
# 神器の説明文 (TextComponentString[])
data modify storage asset:artifact Lore set value ['{"text":"グローブの形をしたクリーパーを両隣に召喚する"}','{"text":"画面を左右に動かしたとき、同じ向きにパンチを行い爆発する"}','{"text":"召喚して12秒経つとパンチを発動しやすくなり"}','{"text":"パンチのスピードが大きく上昇する"}','{"text":"ロケットパンチにあこがれたクリーパーたちの末路","color":"dark_gray"}']
# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
# data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
# data modify storage asset:artifact ConsumeItem.Count set value 1
# data modify storage asset:artifact ConsumeItem.Extra set value
# 使用回数 (int) (オプション)
# data modify storage asset:artifact RemainingCount set value
# 神器を発動できるスロット (string) Wikiを参照
data modify storage asset:artifact Slot set value "auto"
# 神器のトリガー (string) Wikiを参照
data modify storage asset:artifact Trigger set value "onClick"
# 神器の発動条件 (TextComponentString) (オプション)
# data modify storage asset:artifact Condition set value
# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.Damage set value [150]
# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.ElementType set value [None]
# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
# data modify storage asset:artifact AttackInfo.BypassResist set value
# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.IsRangeAttack set value 'every'
# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.AttackRange set value 3
# MP消費量 (int)
data modify storage asset:artifact MPCost set value 120
# MP必要量 (int) (オプション)
# data modify storage asset:artifact MPRequire set value
# MP回復量 (int)
# data modify storage asset:artifact MPHealWhenHit set value
# 神器のクールダウン (int) (オプション)
# data modify storage asset:artifact LocalCooldown set value
# 種別クールダウン ({Type: string, Duration: int}) (オプション)
data modify storage asset:artifact TypeCooldown.Type set value "summon"
data modify storage asset:artifact TypeCooldown.Duration set value 400
# 第二種別クールダウン ({Type: string, Duration: int}) (オプション)
data modify storage asset:artifact SecondaryTypeCooldown.Type set value "shortRange"
data modify storage asset:artifact SecondaryTypeCooldown.Duration set value 180
# グローバルクールダウン (int) (オプション)
# data modify storage asset:artifact SpecialCooldown set value
# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
# data modify storage asset:artifact DisableCooldownMessage set value
# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
# data modify storage asset:artifact DisableMPMessage set value
# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
# data modify storage asset:artifact DisableBreakSound set value
# 扱える神 (string[]) Wikiを参照
data modify storage asset:artifact CanUsedGod set value ["Flora", "Urban", "Rumor"]
# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
# data modify storage asset:artifact CustomNBT set value {}

# 神器の入手用function
function asset:artifact/common/give
Original file line number Diff line number Diff line change
@@ -0,0 +1,8 @@
#> asset:artifact/1634.call_glove_creepers/register
#
# 神器プールへの登録処理
#
# @within tag/function asset:artifact/register

data modify storage asset:artifact RarityRegistry[3] append value [1634]
data modify storage asset:artifact RarityRegistryWithColor.Red[3] append value [1634]
Original file line number Diff line number Diff line change
@@ -0,0 +1,8 @@
#> asset:artifact/1634.call_glove_creepers/trigger/1.trigger
#
# 指定したイベントタイミングで実行されるfunction
#
# @within tag/function asset:artifact/**

# storage asset:idのautoに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
execute if data storage asset:context id{auto:1634} run function asset:artifact/1634.call_glove_creepers/trigger/2.check_condition
Original file line number Diff line number Diff line change
@@ -0,0 +1,12 @@
#> asset:artifact/1634.call_glove_creepers/trigger/2.check_condition
#
# 神器の発動条件をチェックします
#
# @within function asset:artifact/1634.call_glove_creepers/trigger/1.trigger

# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
function asset:artifact/common/check_condition/auto
# 他にアイテム等確認する場合はここに書く

# CanUsedタグをチェックして3.main.mcfunctionを実行する
execute if entity @s[tag=CanUsed] run function asset:artifact/1634.call_glove_creepers/trigger/3.main
Original file line number Diff line number Diff line change
@@ -0,0 +1,35 @@
#> asset:artifact/1634.call_glove_creepers/trigger/3.main
#
# 神器のメイン処理部
#
# @within function asset:artifact/1634.call_glove_creepers/trigger/2.check_condition

# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
function asset:artifact/common/use/auto

# グローブに渡す値
execute store result storage asset:temp 1634.FieldOverride.UserID int 1 run scoreboard players get @s UserID
data modify storage asset:temp 1634.FieldOverride.Damage set value 150d
data modify storage asset:temp 1634.FieldOverride.SwingCooldown set value 5
data modify storage asset:temp 1634.FieldOverride.LifeTime set value 360
data modify storage asset:temp 1634.FieldOverride.EnemyKnockback set value 1.0d
data modify storage asset:temp 1634.FieldOverride.EmpowerTime set value 240
data modify storage asset:temp 1634.FieldOverride.EmpoweredSwingCooldown set value 1
data modify storage asset:temp 1634.FieldOverride.EmpoweredReturnDuration set value 2
data modify storage asset:temp 1634.FieldOverride.EmpoweredHitHoldDuration set value 2

# 右のグローブを召喚する
data modify storage api: Argument.ID set value 1195
data modify storage api: Argument.FieldOverride set from storage asset:temp 1634.FieldOverride
execute anchored eyes positioned ^ ^ ^ rotated ~ 0 positioned ^-1.0 ^-0.3 ^-0.1 rotated as @s run function api:object/summon

# 左のグローブを召喚する
data modify storage api: Argument.ID set value 1196
data modify storage api: Argument.FieldOverride set from storage asset:temp 1634.FieldOverride
execute anchored eyes positioned ^ ^ ^ rotated ~ 0 positioned ^1.0 ^-0.3 ^-0.1 rotated as @s run function api:object/summon

# 演出
playsound entity.creeper.primed player @a ~ ~ ~ 0.7 1.2

# リセット
data remove storage asset:temp 1634
Original file line number Diff line number Diff line change
@@ -0,0 +1,12 @@
#> asset:object/1195.creeper_glove_right/_index.d
# @private

#> tag
# @within function asset:object/1195.creeper_glove_right/**
#declare tag 1195.Owner

#> score_holder
# @within function asset:object/1195.creeper_glove_right/**
#declare score_holder $1195.SwingStart
#declare score_holder $1195.ArcT
#declare score_holder $1195.Expired
Original file line number Diff line number Diff line change
@@ -0,0 +1,18 @@
#> asset:object/1195.creeper_glove_right/init/
#
# Objectのinit時の処理
#
# @within asset:object/alias/1195/init

#> Private
# @private
#declare score_holder $UserID

#vfx
particle explosion ~ ~1 ~ 1.5 1 1.5 0 15 force
playsound entity.generic.explode player @a ~ ~ ~ 1 1

# 所有者の今のyaw(度×100)を振り検出の基準にする
execute store result score $UserID Temporary run data get storage asset:context this.UserID
execute as @a[distance=..64] if score @s UserID = $UserID Temporary store result storage asset:context this.PrevYaw int 1 run data get entity @s Rotation[0] 100
scoreboard players reset $UserID Temporary
Original file line number Diff line number Diff line change
@@ -0,0 +1,17 @@
#> asset:object/1195.creeper_glove_right/kill/
#
# 消滅処理
#
# @within function
# asset:object/1195.creeper_glove_right/tick/
# asset:object/1195.creeper_glove_right/tick/main

#vfx
particle explosion ~ ~1 ~ 1.5 1 1.5 0 15 force
particle large_smoke ~ ~ ~ 0.3 0.3 0.3 0.05 10 normal @a
playsound entity.creeper.hurt player @a ~ ~ ~ 1 0.8
playsound minecraft:entity.creeper.death player @a ~ ~ ~ 1.0 1 0.0
playsound entity.generic.explode player @a ~ ~ ~ 1 0.9

#消滅
kill @s
Original file line number Diff line number Diff line change
@@ -0,0 +1,49 @@
#> asset:object/1195.creeper_glove_right/register
#
# Objectのデータを指定
#
# @within function asset:object/alias/1195/register

# 継承(オプション)
# data modify storage asset:object Extends append value
# function asset:object/extends
# 他のObjectに継承されることを許可するか (boolean) (オプション)
data modify storage asset:object ExtendsSafe set value true
# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
data modify storage asset:object IsAbstract set value false
# Tickするかどうか(boolean) (オプション)
# data modify storage asset:object IsTicking set value

# ID (int)
data modify storage asset:object ID set value 1195
# フィールド(オプション)
data modify storage asset:object Field.UserID set value -1
data modify storage asset:object Field.Damage set value 1d
data modify storage asset:object Field.SwingCooldown set value 1
data modify storage asset:object Field.LifeTime set value 1
data modify storage asset:object Field.EnemyKnockback set value 1.0d
# 左右 (右: 1, 左: -1) と所有者の目からの位置 (m)
data modify storage asset:object Field.Side set value 1
data modify storage asset:object Field.OffsetSide set value 1.0d
data modify storage asset:object Field.OffsetUp set value -0.3d
data modify storage asset:object Field.OffsetForward set value -0.1d
data modify storage asset:object Field.Reach set value 3.0d
# 振り (閾値は度/tick、時間はtick)
data modify storage asset:object Field.SwingThreshold set value 5.0d
data modify storage asset:object Field.SwingDuration set value 3
data modify storage asset:object Field.ReturnDuration set value 10
data modify storage asset:object Field.FinishYaw set value 70.0d
data modify storage asset:object Field.HitHoldDuration set value 15
# 強化 (召喚からEmpowerTime tick後に、振りの各時間を強化後の値へ変える)
data modify storage asset:object Field.EmpowerTime set value 10
data modify storage asset:object Field.EmpoweredSwingCooldown set value 1
data modify storage asset:object Field.EmpoweredReturnDuration set value 1
data modify storage asset:object Field.EmpoweredHitHoldDuration set value 1
data modify storage asset:object Field.EmpoweredSwingThreshold set value 1.0d
# 状態
data modify storage asset:object Field.State set value "idle"
data modify storage asset:object Field.Step set value 0
data modify storage asset:object Field.PrevYaw set value 0
data modify storage asset:object Field.IgnoreBury set value false
data modify storage asset:object Field.ExplodeProgress set value 0
data modify storage asset:object Field.Empowered set value false
Original file line number Diff line number Diff line change
@@ -0,0 +1,11 @@
#> asset:object/1195.creeper_glove_right/summon/
#
# Object召喚処理の呼び出し時に実行されるfunction
#
# @within asset:object/alias/1195/summon

# 元となるEntityを召喚する
execute as 0-0-0-0-0 in minecraft:overworld positioned as @s run tp @s ~ ~ ~ ~ ~
data modify storage asset:temp Args.Rotation set from entity 0-0-0-0-0 Rotation
function asset:object/1195.creeper_glove_right/summon/m with storage asset:temp Args
data remove storage asset:temp Args
Original file line number Diff line number Diff line change
@@ -0,0 +1,7 @@
#> asset:object/1195.creeper_glove_right/summon/m
#
#
#
# @within function asset:object/1195.creeper_glove_right/summon/

$summon item_display ~ ~ ~ {Rotation:$(Rotation),Tags:["ObjectInit"],item:{id:"minecraft:stick",Count:1b,tag:{CustomModelData:20664}},teleport_duration:1}
Original file line number Diff line number Diff line change
@@ -0,0 +1,21 @@
#> asset:object/1195.creeper_glove_right/tick/
#
# Objectのtick時の処理
#
# @within asset:object/alias/1195/tick

# 経過時間を数える
scoreboard players add @s General.Object.Tick 1

# 所有者がいなければ消滅する
execute unless function asset:object/1195.creeper_glove_right/tick/owner run return run function asset:object/1195.creeper_glove_right/kill/

# 状態ごとの処理
function asset:object/1195.creeper_glove_right/tick/main

# リセット
tag @a[tag=1195.Owner,distance=..64] remove 1195.Owner
data remove storage asset:temp 1195
scoreboard players reset $1195.SwingStart Temporary
scoreboard players reset $1195.ArcT Temporary
scoreboard players reset $1195.Expired Temporary
Original file line number Diff line number Diff line change
@@ -0,0 +1,84 @@
#> asset:object/1195.creeper_glove_right/tick/arc/
#
# 進行度の割合$1195.ArcT (0..1000) から円弧上の位置と向きを求めて移動する
#
# @within function
# asset:object/1195.creeper_glove_right/tick/swing/idle
# asset:object/1195.creeper_glove_right/tick/swing/out
# asset:object/1195.creeper_glove_right/tick/swing/back
# asset:object/1195.creeper_glove_right/tick/swing/cooldown

#> Private
# @private
#declare score_holder $T
#declare score_holder $U
#declare score_holder $Side
#declare score_holder $OwnerYaw
#declare score_holder $OwnerPitch
#declare score_holder $Value
#declare score_holder $Calc

# t, u (×1000) と所有者の向き (度×1000)
scoreboard players operation $T Temporary = $1195.ArcT Temporary
scoreboard players set $U Temporary 1000
scoreboard players operation $U Temporary -= $T Temporary
execute store result score $Side Temporary run data get storage asset:context this.Side
execute store result score $OwnerYaw Temporary run data get entity @p[tag=1195.Owner,distance=..64] Rotation[0] 1000
execute store result score $OwnerPitch Temporary run data get entity @p[tag=1195.Owner,distance=..64] Rotation[1] 1000

# 角度 Theta
scoreboard players set $Value Temporary 90
scoreboard players operation $Value Temporary *= $U Temporary
scoreboard players operation $Value Temporary *= $Side Temporary
execute store result storage asset:temp 1195.Arc.Theta double 0.001 run scoreboard players get $Value Temporary
# 見た目のyaw = 所有者のyaw − Side × FinishYaw × t (待機で所有者と同じ向き、到達時に内側へFinishYaw度)
execute store result score $Value Temporary run data get storage asset:context this.FinishYaw 1000
scoreboard players operation $Value Temporary *= $T Temporary
scoreboard players operation $Value Temporary /= $1000 Const
scoreboard players operation $Value Temporary *= $Side Temporary
scoreboard players operation $Calc Temporary = $OwnerYaw Temporary
scoreboard players operation $Calc Temporary -= $Value Temporary
execute store result storage asset:temp 1195.Arc.Yaw double 0.001 run scoreboard players get $Calc Temporary

# 半径 r
execute store result score $Value Temporary run data get storage asset:context this.Reach 1000
execute store result score $Calc Temporary run data get storage asset:context this.OffsetSide 1000
scoreboard players operation $Value Temporary -= $Calc Temporary
scoreboard players operation $Value Temporary *= $T Temporary
scoreboard players operation $Value Temporary /= $1000 Const
scoreboard players operation $Value Temporary += $Calc Temporary
execute store result storage asset:temp 1195.Arc.R double 0.001 run scoreboard players get $Value Temporary
# 前のずれ f
execute store result score $Value Temporary run data get storage asset:context this.OffsetForward 1000
scoreboard players operation $Value Temporary *= $U Temporary
scoreboard players operation $Value Temporary /= $1000 Const
execute store result storage asset:temp 1195.Arc.F double 0.001 run scoreboard players get $Value Temporary
# 高さ h
execute store result score $Value Temporary run data get storage asset:context this.OffsetUp 1000
scoreboard players operation $Value Temporary *= $U Temporary
scoreboard players operation $Value Temporary /= $1000 Const
execute store result storage asset:temp 1195.Arc.H double 0.001 run scoreboard players get $Value Temporary

# 円弧のpitch
scoreboard players operation $Value Temporary = $OwnerPitch Temporary
scoreboard players operation $Value Temporary *= $T Temporary
scoreboard players operation $Value Temporary /= $1000 Const
execute store result storage asset:temp 1195.Arc.Pitch double 0.001 run scoreboard players get $Value Temporary
# 見た目のpitch
execute store result storage asset:temp 1195.Arc.VisPitch double 0.001 run scoreboard players get $OwnerPitch Temporary

# 先読み補正がなければ0にする
execute unless data storage asset:temp 1195.Arc.DX run data modify storage asset:temp 1195.Arc merge value {DX:0d,DY:0d,DZ:0d}

# 移動する
function asset:object/1195.creeper_glove_right/tick/arc/tp.m with storage asset:temp 1195.Arc

# リセット
data remove storage asset:temp 1195.Arc
scoreboard players reset $T Temporary
scoreboard players reset $U Temporary
scoreboard players reset $Side Temporary
scoreboard players reset $OwnerYaw Temporary
scoreboard players reset $OwnerPitch Temporary
scoreboard players reset $Value Temporary
scoreboard players reset $Calc Temporary
Original file line number Diff line number Diff line change
@@ -0,0 +1,7 @@
#> asset:object/1195.creeper_glove_right/tick/arc/tp.m
#
# 所有者の目を基準に、水平の向きで高さと前のずれを取り、円弧の角度とpitchへ回してから半径だけ進んだ位置へ移動する
#
# @within function asset:object/1195.creeper_glove_right/tick/arc/

$execute as @p[tag=1195.Owner,distance=..64] at @s anchored eyes positioned ^ ^ ^ rotated ~ 0 positioned ^ ^$(H) ^$(F) rotated ~$(Theta) $(Pitch) positioned ^ ^ ^$(R) positioned ~$(DX) ~$(DY) ~$(DZ) run tp @e[type=item_display,tag=this,distance=..64,limit=1] ~ ~ ~ $(Yaw) $(VisPitch)
Loading
Loading