Skip to content
Open
Show file tree
Hide file tree
Changes from all commits
Commits
Show all changes
44 commits
Select commit Hold shift + click to select a range
8f2d37c
✨ [Artifact 1432] 廻蛇の玉の神器側の作成
k22992068-crypto May 28, 2026
7fd3b5b
✨ [Artifact 1432] 廻蛇の玉のエフェクト部分以外の実装
k22992068-crypto May 29, 2026
8d3595e
✨ [Artifact 1432] 廻蛇の玉を作成
k22992068-crypto Jun 1, 2026
1574578
🩹 [Artifact 1432] 廻蛇の玉の性能を調整
k22992068-crypto Jun 1, 2026
c5e7022
🎨[Artifact 1432] 廻蛇の玉の継続時間と自傷ダメージの値を神器側で設定できるように変更、その他軽微なミスの修正
k22992068-crypto Jun 2, 2026
72087c4
🎨[Artifact 1432] 廻蛇の玉の不必要なヒット検知を削除
k22992068-crypto Jun 2, 2026
9a93c4a
Merge branch 'master' into dev/mizame_1432
Lapis-LJA Jun 2, 2026
1f13ef2
✨[Artifact 1432] 廻蛇の玉のダメージ処理に天井を追加
k22992068-crypto Jun 2, 2026
cc8abd0
Merge branch 'dev/mizame_1432' of https://github.com/ProjectTSB/Asset…
k22992068-crypto Jun 2, 2026
bdaefc2
🩹[Artifact 1432] 廻蛇の玉のロアを修正
k22992068-crypto Jun 3, 2026
9693eeb
🩹[effect 361] ウロボロス・エコーのロアを修正
k22992068-crypto Jun 3, 2026
4667c20
🎨[Artifact 1432] 廻蛇の玉のダメージ処理時オーナータグを付与するように変更
k22992068-crypto Jun 3, 2026
e5a1308
🩹[Artifact 1432] 廻蛇の玉のエフェクト付与を行うファイルの名前を微修正
k22992068-crypto Jun 3, 2026
51743c6
🩹 [Artifact 1432] 廻蛇の玉のオブジェクトのaliasの謎の空白を削除
k22992068-crypto Jun 3, 2026
7475b6f
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Jun 4, 2026
7f88a0b
🐛[Artifact 1432] 廻蛇の玉がレッドシャードのレジスタに登録されていない問題の修正
k22992068-crypto Jun 5, 2026
84fc466
Merge branch 'dev/mizame_1432' of https://github.com/ProjectTSB/Asset…
k22992068-crypto Jun 5, 2026
0c23705
🎨[Artifact 1432] 廻蛇の玉のダメージ計算式で小数点も計算に含めるように変更
k22992068-crypto Jun 5, 2026
1f0f8b6
🩹 [Artifact 1432] 廻蛇の玉の不必要なsort=ramdomを削除
k22992068-crypto Jun 10, 2026
dc93d06
✨ [Artifact 1432] 廻蛇の玉のヒット音をneutralに変更
k22992068-crypto Jun 10, 2026
762528f
🩹 [Artifact 1432] 廻蛇の玉のダメージ計算に使うOwnerタグの活用を最適化
k22992068-crypto Jun 10, 2026
51cfea4
🎨 [Artifact 1432] 廻蛇の玉のダメージ計算式の最適化
k22992068-crypto Jun 10, 2026
068cc91
✨ [Artifact 1432] 廻蛇の玉の発射物を回転するように変更
k22992068-crypto Jun 12, 2026
c77e0ef
🎨 [Artifact 1432] 廻蛇の玉の玉の回転をleft_rotationで変えるように変更
k22992068-crypto Jun 12, 2026
e515353
🩹 [Artifact 1432] 廻蛇の玉のロアをわかりやすいように微修正
k22992068-crypto Jun 12, 2026
feac3b8
🎨 [Artifact 1432] 廻蛇の玉の回転を最適化
k22992068-crypto Jun 14, 2026
6bc56a1
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Jun 17, 2026
fa56c3e
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Jun 23, 2026
5b2a917
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Sep 21, 2026
a240116
ダメージ上限を神器側で設定できるように変更。ついでにOwner不在時のためのifを追加
k22992068-crypto Oct 8, 2026
839ec18
存在しないファイルを指定している問題を修正
k22992068-crypto Oct 8, 2026
36cb154
いらないデバッグファイルを削除
k22992068-crypto Oct 8, 2026
d687553
Merge branch 'dev/mizame_1432' of https://github.com/ProjectTSB/Asset…
k22992068-crypto Oct 8, 2026
01b15b4
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Oct 8, 2026
9f5437e
エフェクトからのデータ取得処理の条件にオーナーが存在することを追加
k22992068-crypto Oct 18, 2026
b1cc5be
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Oct 18, 2026
a455252
敵の間を反射するように性能を変更+演出の強化
k22992068-crypto Oct 18, 2026
ae26140
不要なエフェクトの処理を削除
k22992068-crypto Oct 18, 2026
c9093bd
Merge branch 'master' into dev/mizame_1432
k22992068-crypto Oct 18, 2026
e58d582
不要な処理を削除
k22992068-crypto Oct 21, 2026
43d6d7b
Merge branch 'dev/mizame_1432' of https://github.com/ProjectTSB/Asset…
k22992068-crypto Oct 21, 2026
2623cb8
消したファイルを参照していた問題を修正
k22992068-crypto Oct 21, 2026
ec044cb
攻撃対象がExtendedCollisionを持っている場合はForwardTargetMobUUIDを使用するように変更
k22992068-crypto Oct 24, 2026
111e2a0
反射の挙動を修正
k22992068-crypto Nov 14, 2026
File filter

Filter by extension

Filter by extension

Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
Original file line number Diff line number Diff line change
@@ -0,0 +1,7 @@
#> asset:artifact/1432.ouroboros_ball/give/1.trigger
#
# 神器の取得処理の呼び出し時に実行されるfunction
#
# @within tag/function asset:artifact/give

execute if data storage asset:context {id:1432} run function asset:artifact/1432.ouroboros_ball/give/2.give
Original file line number Diff line number Diff line change
@@ -0,0 +1,68 @@
#> asset:artifact/1432.ouroboros_ball/give/2.give
#
# 神器の作成部 ここでID等を定義する
#
# @user
# @within function asset:artifact/1432.ouroboros_ball/give/1.trigger

# 神器の説明や消費MPなどをここで設定する。
# 最後にasset:artifact/common/giveを実行することで入手可能。

# 神器のID (int) スプレッドシートの値を入れる
data modify storage asset:artifact ID set value 1432
# 神器のベースアイテム
data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
# 神器の名前 (TextComponentString)
data modify storage asset:artifact Name set value '{"text":"廻蛇の玉","color":"light_purple"}'
# 神器の説明文 (TextComponentString[])
data modify storage asset:artifact Lore set value ['{"text":"敵に玉を投げつけて攻撃する"}','{"text":"ヒット時、5回まで近くの敵に向かって跳ね返り"}','{"text":"2.5秒の間、与えたダメージの80%分"}','{"text":"次のダメージがアップする(最大2000)"}','{"text":"増加するダメージは自身のステータス補正の影響を受けない"}','{"text":"”石ころを投げるより強い!”","color":"gray"}']
# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
# data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
# data modify storage asset:artifact ConsumeItem.Count set value 1
# data modify storage asset:artifact ConsumeItem.Extra set value
# 使用回数 (int) (オプション)
# data modify storage asset:artifact RemainingCount set value
# 神器を発動できるスロット (string) Wikiを参照
data modify storage asset:artifact Slot set value "mainhand"
# 神器のトリガー (string) Wikiを参照
data modify storage asset:artifact Trigger set value "onClick"
# 神器の発動条件 (TextComponentString) (オプション)
# data modify storage asset:artifact Condition set value
# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.Damage set value [40,80]
# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.ElementType set value [Water]
# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
# data modify storage asset:artifact AttackInfo.BypassResist set value
# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.IsRangeAttack set value "never"
# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
data modify storage asset:artifact AttackInfo.AttackRange set value 30
# MP消費量 (int)
data modify storage asset:artifact MPCost set value 60
# MP必要量 (int) (オプション)
# data modify storage asset:artifact MPRequire set value
# MP回復量 (int)
# data modify storage asset:artifact MPHealWhenHit set value
# 神器のクールダウン (int) (オプション)
# data modify storage asset:artifact LocalCooldown set value
# 種別クールダウン ({Type: string, Duration: int}) (オプション)
data modify storage asset:artifact TypeCooldown.Type set value "longRange"
data modify storage asset:artifact TypeCooldown.Duration set value 30
# グローバルクールダウン (int) (オプション)
# data modify storage asset:artifact SpecialCooldown set value
# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
# data modify storage asset:artifact DisableCooldownMessage set value
# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
# data modify storage asset:artifact DisableMPMessage set value
# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
# data modify storage asset:artifact DisableBreakSound set value
# 扱える神 (string[]) Wikiを参照
data modify storage asset:artifact CanUsedGod set value ["Flora","Urban", "Rumor"]
# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
# data modify storage asset:artifact CustomNBT set value {}

# 神器の入手用function
function asset:artifact/common/give
Original file line number Diff line number Diff line change
@@ -0,0 +1,8 @@
#> asset:artifact/1432.ouroboros_ball/register
#
# 神器プールへの登録処理
#
# @within tag/function asset:artifact/register

data modify storage asset:artifact RarityRegistry[4] append value [1432]
data modify storage asset:artifact RarityRegistryWithColor.Red[4] append value [1432]
Original file line number Diff line number Diff line change
@@ -0,0 +1,8 @@
#> asset:artifact/1432.ouroboros_ball/trigger/1.trigger
#
# 指定したイベントタイミングで実行されるfunction
#
# @within tag/function asset:artifact/**

# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
execute if data storage asset:context id{mainhand:1432} run function asset:artifact/1432.ouroboros_ball/trigger/2.check_condition
Original file line number Diff line number Diff line change
@@ -0,0 +1,12 @@
#> asset:artifact/1432.ouroboros_ball/trigger/2.check_condition
#
# 神器の発動条件をチェックします
#
# @within function asset:artifact/1432.ouroboros_ball/trigger/1.trigger

# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
function asset:artifact/common/check_condition/mainhand
# 他にアイテム等確認する場合はここに書く

# CanUsedタグをチェックして3.main.mcfunctionを実行する
execute if entity @s[tag=CanUsed] run function asset:artifact/1432.ouroboros_ball/trigger/3.main
Original file line number Diff line number Diff line change
@@ -0,0 +1,30 @@
#> asset:artifact/1432.ouroboros_ball/trigger/3.main
#
# 神器のメイン処理部
#
# @within function asset:artifact/1432.ouroboros_ball/trigger/2.check_condition

# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
function asset:artifact/common/use/mainhand

# 演出
execute anchored eyes positioned ^ ^ ^0.5 run playsound minecraft:entity.breeze.jump player @a ~ ~ ~ 1.0 0.8 0.0
execute anchored eyes positioned ^ ^ ^0.5 run playsound minecraft:entity.breeze.jump player @a ~ ~ ~ 1.0 0.65 0.0

# ここから先は神器側の効果の処理を書く

# 玉を発射(ダメージは8発連続で当てられれば4倍くらいになる。単体の敵に4回連続当て続けられたら強いくらいの感覚)
data modify storage api: Argument.ID set value 1158
execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
#ダメージ
execute store result storage api: Argument.FieldOverride.Damage double 1 run random value 40..80
#引継ぎダメージ保持時間
data modify storage api: Argument.FieldOverride.Duration set value 50
#引継ぎダメージ上限
data modify storage api: Argument.FieldOverride.AdditionalDamageLimit set value 2000
#反射回数上限
data modify storage api: Argument.FieldOverride.ReflectionLimit set value 5
#射程(Range*0.5m)
data modify storage api: Argument.FieldOverride.Range set value 60

execute anchored eyes positioned ^-0.2 ^-0.2 ^ run function api:object/summon
Original file line number Diff line number Diff line change
@@ -0,0 +1,7 @@
#> asset:effect/0361.ouroboros_echo/_/register
#
#
#
# @within tag/function asset:effect/register

execute if data storage asset:context {id:361} run function asset:effect/0361.ouroboros_echo/register
Original file line number Diff line number Diff line change
@@ -0,0 +1,39 @@
#> asset:effect/0361.ouroboros_echo/register
#
# Effectのデータを指定
#
# @within function asset:effect/0361.ouroboros_echo/_/register

# ExtendsSafe (boolean) (default = false)
# data modify storage asset:effect ExtendsSafe set value true
# ID (int)
data modify storage asset:effect ID set value 361
# 名前 (TextComponentString)
data modify storage asset:effect Name set value '{"text":"ウロボロス・エコー","color":"light_purple"}'
# 説明文 (TextComponentString[])
data modify storage asset:effect Description set value ['{"text":"廻蛇の玉のダメージが上昇する"}']
# 効果時間 (int) (default = API || error)
# data modify storage asset:effect Duration set value
# スタック (int) (default = API || 1)
data modify storage asset:effect Stack set value 1
# 効果時間の操作方法 (default = API || "replace")
# data modify storage asset:effect DurationOperation set value
# スタックの操作方法 (default = API || "replace")
# data modify storage asset:effect StackOperation set value
# 最大効果時間 (int) (default = 2147483647)
# data modify storage asset:effect MaxDuration set value
# 最大スタック (int) (default = 2147483647)
data modify storage asset:effect MaxStack set value 1
# 悪い効果か否か (boolean)
data modify storage asset:effect IsBadEffect set value false
# 死亡時のエフェクトの処理 (default = "remove")
# data modify storage asset:effect ProcessOnDied set value
# 消すのに必要なレベル (int) (default = 1)
data modify storage asset:effect RequireClearLv set value 3
# エフェクトをUIに表示するか (boolean) (default = true)
# data modify storage asset:effect Visible set value
# エフェクトのスタックををUIに表示するか (boolean) (default = true)
data modify storage asset:effect StackVisible set value false

# フィールド
data modify storage asset:effect Field.DamageHolder set value 0
Original file line number Diff line number Diff line change
@@ -0,0 +1,13 @@
#> asset:object/1158.ouroboros_ball/_index.d
# @private

#> score_holder
# @within
# function asset:object/1158.ouroboros_ball/hit_entity/**
#declare score_holder $Temporary
#declare score_holder $HitEnemyID

#> tag
# @within function asset:object/1158.ouroboros_ball/hit_entity/**
#declare tag 13S.Owner
#declare tag 13S.HitEnemy
Original file line number Diff line number Diff line change
@@ -0,0 +1,8 @@
#> asset:object/1158.ouroboros_ball/detect_hit_entity/
#
# 継承先などから実行される処理
#
# @within asset:object/alias/1158/detect_hit_entity

# ヒット検知
execute positioned ~-0.5 ~-0.5 ~-0.5 if entity @e[type=#lib:living_without_player,tag=!Uninterferable,dx=0,sort=nearest,limit=1] run data modify storage asset:context IsHitEntity set value true
Comment thread
Lapis-LJA marked this conversation as resolved.
Resolved
Original file line number Diff line number Diff line change
@@ -0,0 +1,48 @@
#> asset:object/1158.ouroboros_ball/hit_entity/
#
# ヒット時の処理
#
# @within function asset:object/alias/1158/hit_entity
#> private
# @private
#declare score_holder $OwnerID

#Hitした敵にTagを付与
execute positioned ~-0.5 ~-0.5 ~-0.5 as @e[type=#lib:living_without_player,tag=!Uninterferable,dx=0,sort=nearest,limit=1] run tag @s add 13S.HitEnemy

#直前にヒットしている敵ならリセットしてreturn(対象がExtendedCollisionを持っている場合はForwardTargetMobUUIDと比較)
execute store result score $HitEnemyID Temporary run data get storage asset:context this.HitEnemyID
execute if score @e[tag=13S.HitEnemy,tag=!ExtendedCollision,distance=..5,sort=nearest,limit=1] MobUUID = $HitEnemyID Temporary run return run function asset:object/1158.ouroboros_ball/hit_entity/reset
execute if score @e[tag=13S.HitEnemy,tag=ExtendedCollision,distance=..5,sort=nearest,limit=1] ForwardTargetMobUUID = $HitEnemyID Temporary run return run function asset:object/1158.ouroboros_ball/hit_entity/reset

#vfx
playsound minecraft:entity.ender_dragon.hurt neutral @a ~ ~ ~ 0.6 1.33 0.0
playsound minecraft:entity.player.attack.strong neutral @a ~ ~ ~ 1.0 0.7 0.0
particle block lapis_block ~ ~ ~ 0 0 0 1 20

# オーナーの特定
execute store result score $OwnerID Temporary run data get storage asset:context this.UserID
execute as @a if score @s UserID = $OwnerID Temporary run tag @s add 13S.Owner

#ダメージ処理
execute as @e[tag=13S.HitEnemy,distance=..5,sort=nearest,limit=1] run function asset:object/1158.ouroboros_ball/hit_entity/damage

#同じ本体に属する敵(本体・追加当たり判定)も反射先の候補から外す
execute store result score $HitEnemyID Temporary run data get storage asset:context this.HitEnemyID
execute as @e[type=#lib:living_without_player,tag=!13S.HitEnemy,tag=!ExtendedCollision,distance=..8] if score @s MobUUID = $HitEnemyID Temporary run tag @s add 13S.HitEnemy
execute as @e[type=#lib:living_without_player,tag=ExtendedCollision,tag=!13S.HitEnemy,distance=..8] if score @s ForwardTargetMobUUID = $HitEnemyID Temporary run tag @s add 13S.HitEnemy

# リセット
scoreboard players reset $OwnerID Temporary
scoreboard players reset $HitEnemyID Temporary
tag @a remove 13S.Owner

#反射回数が0になったら玉を消す
execute if data storage asset:context this{ReflectionLimit:0} run function asset:object/call.m {method:"kill"}

#8m以内に敵がいるなら、向きを変える。そうでない時は玉を消す。
execute unless data storage asset:context this{ReflectionLimit:0} if entity @e[type=#lib:living_without_player,tag=!13S.HitEnemy,tag=!Uninterferable,distance=..8] run function asset:object/1158.ouroboros_ball/hit_entity/reflect
execute unless data storage asset:context this{ReflectionLimit:0} unless entity @e[type=#lib:living_without_player,tag=!13S.HitEnemy,tag=!Uninterferable,distance=..8] run function asset:object/call.m {method:"kill"}

#ヒットタグもリセット
tag @e[type=#lib:living_without_player,distance=..5] remove 13S.HitEnemy
Comment thread
Lapis-LJA marked this conversation as resolved.
Resolved
Original file line number Diff line number Diff line change
@@ -0,0 +1,47 @@
#> asset:object/1158.ouroboros_ball/hit_entity/damage
#
# damage処理
#
# @within function asset:object/1158.ouroboros_ball/hit_entity/

#> private
# @private
#declare score_holder $DamageHolder
#declare score_holder $AdditionalDamageLimit

#ヒットした敵のIDを取得(対象がExtendedCollisionを持っている場合はForwardTargetMobUUIDを取得)
execute if entity @s[tag=!ExtendedCollision] store result storage asset:context this.HitEnemyID int 1 run scoreboard players get @s MobUUID
execute if entity @s[tag=ExtendedCollision] store result storage asset:context this.HitEnemyID int 1 run scoreboard players get @s ForwardTargetMobUUID

# effectの情報を取得
data modify storage api: Argument.ID set value 361
execute as @a[tag=13S.Owner] run function api:entity/mob/effect/get/from_id
execute if entity @a[tag=13S.Owner] store result score $DamageHolder Temporary run data get storage api: Return.Effect.Field.DamageHolder


# ダメージ計算
# 今回追加するダメージの攻撃補正後のダメージを計算する。
data modify storage api: Argument.Damage set from storage asset:context this.Damage
data modify storage api: Argument.AttackType set value "Physical"
data modify storage api: Argument.ElementType set value "Water"
execute if entity @a[tag=13S.Owner] as @a[tag=13S.Owner] run function api:damage/modifier
# 前に計算したダメージ量(10倍)に保持している前のダメージ量(8倍)を足して0.1倍して与えるダメージに入れる。
execute store result score $Temporary Temporary run data get storage api: Argument.Damage 10
scoreboard players operation $Temporary Temporary += $DamageHolder Temporary
execute store result storage api: Argument.Damage double 0.1 run scoreboard players get $Temporary Temporary
# 今回与えるダメージの八割の10倍(8倍)を保持する。(最大でAdditionalDamageLimitの値まで)
execute store result score $Temporary Temporary run data get storage api: Argument.Damage 8
execute store result score $AdditionalDamageLimit Temporary run data get storage asset:context this.AdditionalDamageLimit 10
scoreboard players operation $Temporary Temporary < $AdditionalDamageLimit Temporary
scoreboard players operation $DamageHolder Temporary = $Temporary Temporary
# 相手の耐性を考慮してダメージをあたえる。
function api:damage/
function api:damage/reset

# effectの付与
execute if entity @a[tag=13S.Owner] as @a[tag=13S.Owner] run function asset:object/1158.ouroboros_ball/hit_entity/effect_give

# リセット
scoreboard players reset $Temporary Temporary
scoreboard players reset $DamageHolder Temporary
scoreboard players reset $AdditionalDamageLimit Temporary
Comment thread
Lapis-LJA marked this conversation as resolved.
Resolved
Original file line number Diff line number Diff line change
@@ -0,0 +1,12 @@
#> asset:object/1158.ouroboros_ball/hit_entity/effect_give
#
# effect付与用
#
# @within function asset:object/1158.ouroboros_ball/hit_entity/damage

# エフェクト付与
data modify storage api: Argument.ID set value 361
data modify storage api: Argument.Duration set from storage asset:context this.Duration
execute store result storage api: Argument.FieldOverride.DamageHolder int 1 run scoreboard players get $Temporary Temporary
function api:entity/mob/effect/give
function api:entity/mob/effect/reset
Original file line number Diff line number Diff line change
@@ -0,0 +1,12 @@
#> asset:object/1158.ouroboros_ball/hit_entity/reflect
#
# 反射処理
#
# @within function asset:object/1158.ouroboros_ball/hit_entity/

#反射回数を1減らす
execute store result storage asset:context this.ReflectionLimit int 0.9999999999 run data get storage asset:context this.ReflectionLimit 1
#向きを変える
tp @s ^ ^ ^ facing entity @e[type=#lib:living_without_player,tag=!13S.HitEnemy,tag=!Uninterferable,distance=..8,sort=random,limit=1] eyes

@tatuharu tatuharu Oct 26, 2026 •

Copy link
Copy Markdown
Member

Choose a reason for hiding this comment

The reason will be displayed to describe this comment to others. Learn more.

黒龍のように追加当たり判定(ExtendedCollision)を複数持つ敵に当たると、反射先に同じ敵の別の追加当たり判定が選ばれることがあります。玉がそこへ当たっても、hit_entity/.mcfunction の16行目で ForwardTargetMobUUID が this.HitEnemyID と一致して return するため、ダメージも反射も起きません。玉は別の敵かブロックに当たるか、射程が尽きるまで直進します。Lapis-LJA さんが指摘した点のうち、命中済みの判定は本体単位になりましたが、反射先の選択はまだ本体単位になっていません。

反射先の候補から外しているのは、この行と hit_entity/.mcfunction の39・40行目のどちらも、同じファイルの11行目で 13S.HitEnemy を付けた entity だけです。黒龍は asset:mob/0410.heiloang/init/locator で locator の slime すべてに Enemy と ExtendedCollision を付け、Uninterferable を付けるのは無敵の間(tick/util/start_invulnerable_locator)だけです。そのため、8m以内にある別の locator は反射先の候補に入ります。

MobUUID(ExtendedCollision なら ForwardTargetMobUUID)が this.HitEnemyID と一致する entity も候補から外せば、別の敵へ向かうようになります。タグで外す場合は、43行目でタグを外す範囲も8mにそろえる必要があります。

検証用サーバー(Minecraft 1.20.4、このPRの head ec044cb)で確かめました。同じ本体へ転送する追加当たり判定を3つ並べてそのうち1つに玉を当てると、7回とも反射先に残りの2つのどちらかが選ばれ、玉はそこを通り抜けて直進しました。通り抜けるあいだ本体の体力も ReflectionLimit も変わらず、反射の効果音(block.glass.break)も届きませんでした。trace を取った1回では、そのあいだに呼ばれた hit_entity 7回がすべて16行目の return で終わっていました。8m以内に別の敵(ハスク)も置いた6回では、最初の反射先は同じ敵の追加当たり判定が2回、ハスクが4回でした。残りの2つを別の本体へ転送させた対照(3回)では、そこへ当たるたびにダメージと反射が起きました。黒龍そのものは召喚せず、本体には黒龍の本体と同じタグを付けた slime を、追加当たり判定には asset:mob/0410.heiloang/init/locator を実行した slime を使い、右クリックは ClickCarrotEvent を1にして代えています。修正案は試していません。

Copy link
Copy Markdown
Member

Choose a reason for hiding this comment

The reason will be displayed to describe this comment to others. Learn more.

未解消です。111e2a068で、命中した敵と同じ本体の判定にも13S.HitEnemyを付けるようになり、同じ本体の別の追加当たり判定へ反射することはなくなりました。ただ、タグを付けるのは8m以内なのに、hit_entity/.mcfunctionの48行目でタグを外すのは5m以内のままです。命中点から5〜8mにある判定にはタグが残り、その判定はあとから撃った玉の反射先にも選ばれなくなります。

検証用サーバー(Minecraft 1.20.4、Asset 111e2a0、TheSkyBlessing bfb8eb9de)で、前回と同じ配置(同じ本体へ転送する追加当たり判定A・B・C)でAに当てました。玉はAにダメージを与えたあと、B・Cへは向かわずに消えましたが、Aの命中点から約5.3mのB・Cには13S.HitEnemyが残りました。そのままB・Cの転送先を別の本体に変えて撃つと、3回ともAに当たったあとに玉が消え、B・Cの本体にはダメージが入りませんでした。ec044cbでは、この条件で毎回B・Cへ反射してダメージが入っています。残ったタグを消してから撃つと、AとCの間で反射してダメージが入りました。

前回のコメントのとおり、48行目でタグを外す範囲も8mにそろえると、タグは残らなくなるはずです。こちらでは試していません。

#vfx
playsound minecraft:block.glass.break player @a ~ ~ ~ 1.0 0.65 0.0
Original file line number Diff line number Diff line change
@@ -0,0 +1,9 @@
#> asset:object/1158.ouroboros_ball/hit_entity/reset
#
# return用リセット処理
#
# @within function asset:object/1158.ouroboros_ball/hit_entity/

# リセット
scoreboard players reset $HitEnemyID Temporary
tag @e[type=#lib:living_without_player,distance=..5] remove 13S.HitEnemy
Original file line number Diff line number Diff line change
@@ -0,0 +1,30 @@
#> asset:object/1158.ouroboros_ball/register
#
# Objectのデータを指定
#
# @within function asset:object/alias/1158/register

# 継承(オプション)
data modify storage asset:object Extends append value 1
function asset:object/extends
# 他のObjectに継承されることを許可するか (boolean) (オプション)
# data modify storage asset:object ExtendsSafe set value
# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
data modify storage asset:object IsAbstract set value false
# Tickするかどうか(boolean) (オプション)
# data modify storage asset:object IsTicking set value

# ID (int)
data modify storage asset:object ID set value 1158
# フィールド(オプション)
data modify storage asset:object Field.Speed set value 2
data modify storage asset:object Field.Range set value 1
data modify storage asset:object Field.MovePerStep set value 0.5
data modify storage asset:object Field.Damage set value 1
data modify storage asset:object Field.UserID set value -1
data modify storage asset:object Field.Duration set value 1
data modify storage asset:object Field.Spin set value 4
data modify storage asset:object Field.SpinInterval set value 2
data modify storage asset:object Field.AdditionalDamageLimit set value 1
data modify storage asset:object Field.ReflectionLimit set value 1
data modify storage asset:object Field.HitEnemyID set value -1
Loading
Loading